Sonifying the Tides with J

NB. tides.ijs, sonify the tides using harmonic constituent data from
NB. NOAA.
NB.
NB. Copyright © 2025 Remington Furman
NB.
NB. SPDX-License-Identifier: MIT
NB.
NB. Permission is hereby granted, free of charge, to any person
NB. obtaining a copy of the software demonstrated in code cells (the
NB. "Software"), to deal in the Software without restriction, including
NB. without limitation the rights to use, copy, modify, merge, publish,
NB. distribute, sublicense, and/or sell copies of the Software, and to
NB. permit persons to whom the Software is furnished to do so, subject
NB. to the following conditions:
NB.
NB. The above copyright notice and this permission notice shall be
NB. included in all copies or substantial portions of the Software.
NB.
NB. THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
NB. EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
NB. MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
NB. NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS
NB. BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN
NB. ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
NB. CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
NB. SOFTWARE.

NB. Exit on error:
9!:29]1[9!:27'2!:55]1'

NB. Use ASCII boxes:
boxdraw_j_ 1

NB. wav.ijs customizes some code from the media/wav addon.
load './wav.ijs'

NB. Save as a .wav file.
save_wav=: dyad define
  (SAMPLE_RATE wavmake x) 1!:2 <y
)

NB. Adapted from https://code.jsoftware.com/wiki/User:Devon_McCormick/Palettes
round_even=: monad define
  <.y+0.5*(0~:2|<.y)+.0.5~:1|y
)

NB. Audio setup
SAMPLE_RATE=: 44100 NB. Hz
SAMPLE_SIZE=: 16    NB. bits

NB. Scaling factors
NB. TODO: Determine max amplitude encountered at any station.
GAIN=: 0.3  NB. Allow for headroom.
MAX_PCM_AMP=: (2^(SAMPLE_SIZE-1))*GAIN
FT_TO_AMP=: MAX_PCM_AMP % 13.0
DPH_TO_RPS=: 2p1%(60*60*360.0)  NB. (degrees/hour) to (rad/second)
FREQ_SCALE=: 60*60*10000.0      NB. times realtime

NB. Synthesize a single harmonic constituent.
NB. x: number of output samples
NB. y: harmonic constituents (amplitude, phase, speed)
synth_harcon=: dyad define "0 1
  amp=. 0{y
  phase=. 360 %~ 2p1 * 1{y
  ang_vel=. FREQ_SCALE * DPH_TO_RPS*(2{y) % SAMPLE_RATE
  phases=. phase + 2p1|ang_vel*(i. x)
  ]samps=. amp * 1 o. phases
)

NB. Synthesize all the harmonic constituents at a tide station and
NB. save the waveform as a .wav audio file.
NB. x: number of output samples
NB. y: boxed station info
synth_station=: dyad define
  id=.".>{.{.{. y
  harcons=.".>(3 4 5) {"1 y NB. Just the facts, please.
  feet=.+/ x synth_harcon harcons
  samps=. round_even FT_TO_AMP*feet
  echo (":id)

  samps save_wav './output/', (":id), '.wav'
  0  NB. We only care about side-effects, so return a dummy value.
)

NB. Read harmonic constituents:
load 'tables/csv'
dat=: readcsv jpath 'harcon_amp.csv'

NB. Group and box each station:
stations=: ({."1 dat) </. dat

NB. Uncomment to use a short dataset for testing:
NB. stations=: 100{.stations

main=: monad define
  DUR_SEC=. 10.0
  DUR_SAMP=. round_even SAMPLE_RATE*DUR_SEC

  if. 0 do.
    NB. Single threaded
    DUR_SAMP (synth_station >)"0 stations
  else.
    NB. Multi-threaded.
    NB. Initialize threadpool 0 with N-1 threads.
    {{0 T.0}}^:] <: {. 8 T. ''
    ]&.> DUR_SAMP (synth_station >)t.''"0 stations
    NB. The ]&.> verb waits for every pyx to be populated, but is
    NB. otherwise a no-op.
    NB. J9.6 will crash if exit is called and tasks are still running.
    NB. J9.7 won't crash, but also doesn't wait for unfinished threads.
  end.
)

main''
exit''