Running Stats with Awk

#!/usr/bin/awk -f

# Copyright (C) 2024 Remington Furman
#
# Permission is hereby granted, free of charge, to any person
# obtaining a copy of this software and associated documentation files
# (the "Software"), to deal in the Software without restriction,
# including without limitation the rights to use, copy, modify, merge,
# publish, distribute, sublicense, and/or sell copies of the Software,
# and to permit persons to whom the Software is furnished to do so,
# subject to the following conditions:
#
# The above copyright notice and this permission notice shall be
# included in all copies or substantial portions of the Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
# EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
# MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
# NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS
# BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN
# ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
# CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
# SOFTWARE.

# This prints running statistics for a single input variable.
#
# It implements the Welford algorithm as described by:
# https://www.johndcook.com/blog/standard_deviation/
#
# It also calculates the root-mean-square (RMS) of the input.

BEGIN {OFS=", ";        print  "n, x, sum, mean, var, stddev, rms"}
function print_stats() {print NR, $1, sum, currM, var, sqrt(var), sqrt(sum2/NR)}

NR==1 {
    sum = prevM = currM = $1
    sum2 = $1 * $1
    var = prevS = 0.0
    print_stats()
}

NR!=1 {
    sum  += $1
    sum2 += $1 * $1
    currM = prevM + ($1 - prevM)/NR
    currS = prevS + ($1 - prevM)*($1 - currM)
    prevM = currM
    prevS = currS
    var   = currS/(NR-1)
    print_stats()
}

for i in {1..100} ; do echo $RANDOM ; done > rand.txt
gawk -v OFMT="%.16g" -f ./stats.awk rand.txt > rand_stats.csv